// temp is the variable to hold the input from analog0
int temp = 0 ;

// the LED is a multiplexed module
// anode1 is the ones digit
// anode10 is the tens digit
volatile int anode1=12;
volatile int anode10=13;

volatile int anode=0;

volatile int lowdisp=0;
volatile int highdisp=0;

// these are the individual segments
// I just found it easier to visual and map out
// as a discrete process
byte blank = 0b11111111;
byte seg_a = 0b11111110;
byte seg_b = 0b11111101;
byte seg_c = 0b11111011;
byte seg_d = 0b11110111;
byte seg_e = 0b11101111;
byte seg_f = 0b11011111;
byte seg_g = 0b10111111;

// and then convert the segments into numbers
// this could have been combined into a single
// process, but as above, I found it better for
// visualization
byte one = seg_b & seg_c;
byte two = seg_a & seg_b & seg_g & seg_e & seg_d;
byte three = seg_a & seg_b & seg_g & seg_c & seg_d;
byte four = seg_f & seg_b & seg_g & seg_c; 
byte five = seg_a & seg_f & seg_g & seg_c & seg_d;
byte six = seg_a & seg_f & seg_g & seg_c & seg_d & seg_e;
byte seven = seg_a & seg_b & seg_c;
byte eight = seg_a & seg_b & seg_c & seg_d & seg_e & seg_f & seg_g;
byte nine = seg_a & seg_b & seg_c & seg_g & seg_f;
byte zero = seg_a & seg_b & seg_c & seg_d & seg_e & seg_f;


void setup() {

// use the 1.1v internal reference of the Mega168
  analogReference(INTERNAL);

// set the LED modes and make sure they are blank  
  pinMode (anode1,OUTPUT);
  pinMode (anode10,OUTPUT);
  digitalWrite(anode1,LOW);
  digitalWrite(anode10,LOW);

// these correspond to digital0-7
// digital 0 and digitial 1 are normally used for
// usart communication, so we cannot use the hardware
// serial port now
  DDRD = 0b01111111; 
  PORTD=blank;

// the temperature is read during an interrupt loop
// I am using timer/counter1 for no other reason than
// it is there. this is in overflow mode, on a fairly
// fast prescaler, since it is a 16-bit timer
  TCCR1A=0;
  TCCR1B = (0<<CS10) | (0<<CS11) | (1<<CS12);
  TIMSK1 = (1<<TOIE1);

}

void loop() {
  
// the main loop consists of nothing but preparing the
// LEDs 

// modulo 10 gives me the ones digit, and then convert
// that into the segment display
  lowdisp=temp%10;
  checkcaselow();

// division by 10 gives the 10s digit
  highdisp=temp/10;
  checkcasehigh();

// set one dislay on, and write the digit
  anode=LOW;
  writedigit();

// then set the other display on and write the digit
  anode=HIGH;
  writedigit();

}

void writedigit(){

// blank out any previous data
  PORTD=blank;

// this is just a sloppy toggle routine
// if we are writing the "low" (ones) digit,
// make sure that the proper digit is enabled
if (anode==LOW) {
  digitalWrite(anode1,HIGH);
  digitalWrite(anode10,LOW);
  PORTD=lowdisp;
  }  

// ditto from above, make sure that the
// 10s digit is the only one enabled
if (anode==HIGH) {
  digitalWrite(anode1,LOW);
  digitalWrite(anode10,HIGH);
  PORTD=highdisp;
  }

// a small delay to prevent flicker
delayMicroseconds(200);
}

// checkcaselow just converts numerics into the seven
// segments
void checkcaselow()
{
  switch(lowdisp){
    case 1:
      lowdisp=one;
      break;
    case 2:
      lowdisp=two;
      break;
    case 3:
      lowdisp=three;
      break;
    case 4:
      lowdisp=four;
      break;
    case 5:
      lowdisp=five;
      break;
    case 6:
      lowdisp=six;
      break;
    case 7:
      lowdisp=seven;
      break;
    case 8:
      lowdisp=eight;
      break;
    case 9:
      lowdisp=nine;
      break;
    case 0:
      lowdisp=zero;
      break;
    default:
      lowdisp=blank;
  }
}

// and this does the same
void checkcasehigh()
{
  switch(highdisp){
    case 1:
      highdisp=one;
      break;
    case 2:
      highdisp=two;
      break;
    case 3:
      highdisp=three;
      break;
    case 4:
      highdisp=four;
      break;
    case 5:
      highdisp=five;
      break;
    case 6:
      highdisp=six;
      break;
    case 7:
      highdisp=seven;
      break;
    case 8:
      highdisp=eight;
      break;
    case 9:
      highdisp=nine;
      break;
    default:
      highdisp=blank;
  }
}

// the timer/counter1 interrupt vector
// just read in analog0 and exit
// 
// todo:
// with only a two digit display, there should be some
// error checking for temps greater than 100 degrees6

// the calculation for the temperature module is as follows:
// analog0 returns data in a 10-bit (0-1023) number. the 
// lm34 returns the temperature in 10mv increments. 
// we need to multiple that number by the internal voltage
// reference, 1.1v, and then mutiply THAT by 100 so that we 
// can divide by 1024 (a 10-bit number) to aquire the temperature
// in a "human" format
ISR(TIMER1_OVF_vect){
temp = analogRead(0);
temp=(1.1*temp*100.0)/1024.0;
}